Подключение к SQL-серверу из 1С:Предприятие 8 (пример кода)

Опубликовано 22.06.2016 автором Виталий Онянов

Logo_1c_8_RazradotkaВ данной статье приведены экземпляры кода на языке 1С, которые позволяют подключаться к базе данных на SQL-сервере, получать из нее данные, а также записывать новые и обновлять существующие записи в таблицах этой базы данных. Код протестирован на платформе 8.3.5, а также на версиях SQL Server 2008 R2 и SQL Server 2012. Операционная система Windows Server 2008 и Windows Server 2012. Есть предположение, что указанный код будет работать и на других версиях 1С, SQL и Windows.

 

0. Оглавление

  1. Постановка задачи
  2. Подключение к SQL-серверу
  3. Добавление записей в таблицу
  4. Обновление записей в таблице
  5. Просмотр выборки из таблицы
  6. Удаление записей из таблицы
  7. Закрытие соединения
  8. Общий текст процедуры

1. Постановка задачи

Итак, имеется SQL-сервер с адресом WIN2012\TEST_SQL. Для подключения используется имя входа SQL-сервера UserDB с паролем Pass123456.

podkly-k-sql-iz-1s_004

На сервере размещена база данных с именем TestDB. В базе имеется таблица с именем Table_1, в которой 3 столбца:

  • C_DateTime, с типом datetime
  • C_Char, с типом char(50)
  • C_Numeric, с типом numeric(18,0)

podkly-k-sql-iz-1s_001

Изначально таблица пустая:

podkly-k-sql-iz-1s_002

У пользователя UserDB есть права на чтение и запись в базу данных TestDB. В данном случае пользователь является владельцем указанной базы данных.

podkly-k-sql-iz-1s_003

Требуется научиться записывать в базу данных и читать из базы данных из 1С при помощи прямых запросов к SQL-серверу.

2. Подключение к SQL-серверу

Весь приведенный ниже код может работать как на клиенте, так и на сервере. Главное чтобы был доступен COM-объект «ADODB» (подробнее о данной библиотеке можно прочитать, например, здесь). Также с клиента (или с сервера, смотря где выполняется код) должен быть доступен указанный SQL-сервер (настроено правило в Брандмауере для возможности внешнего подключения). Код приводится совсем простой, для понимания с чего вообще начинать разработчику, который раньше с этим не сталкивался.

Итак, для подключения необходимо создать COM-объект «ADODB». Для этого выполняется код 1С:

&НаКлиенте
Процедура ВыполнитьОбработку(Команда)

    //Инициализация переменных
    ИмяСервераSQL = "WIN2012\TEST_SQL";
    ПользовательSQL = "UserDB";
    ПарольSQL = "Pass123456";
    БазаДанныхSQL = "TestDB";
    ТаблицаSQL = "Table_1";


    /////////////////////////////////////////
    //Подключение к SQL-серверу
    Попытка
        Соединение  = Новый COMОбъект("ADODB.Connection");
        Команда     = Новый COMОбъект("ADODB.Command");
        Выборка     = Новый COMОбъект("ADODB.RecordSet");
        Соединение.ConnectionString =
            "driver={SQL Server};" +
            "server="+ИмяСервераSQL+";"+
            "uid="+ПользовательSQL+";"+
            "pwd="+ПарольSQL+";"+
            "database="+БазаДанныхSQL+";";
        Соединение.ConnectionTimeout = 30;
        Соединение.CommandTimeout = 600;
        //Открытие соединение
        Соединение.Open();
        Команда.ActiveConnection   = Соединение;
        Сообщить("Успешное подключение!");
    Исключение
        Сообщить(ОписаниеОшибки());
        Возврат;
    КонецПопытки;

КонецПроцедуры

Результат работы в 1С:Предприятии:

podkly-k-sql-iz-1s_005

Теперь, в общем то, можно выполнять любой запрос SQL через данный COM-объект. Посмотрим как это делать на самых распространенных примерах.

3. Добавление записей в таблицу

Теперь добавим новую строку в нашу пока еще пустую таблицу. Для этого необходимо выполнить код:

    /////////////////////////////////////////
    //Добавляем запись в таблицу
    ТекДата = ТекущаяДата();
    ТекСтрока = "Запись строки";
    ТекЧисло = 123456;

    //Приобразуем данные
    Если НЕ ЗначениеЗаполнено(ТекДата) Тогда
        //Для пустой даты необходимо отправлять 01.01.1753
        ТекДата = Дата(1753,1,1);
    КонецЕсли;
    ТекЧисло = Формат(ТекЧисло,"ЧГ="); //Удаляем пробелы

    ТекстТекущейИнструкции =
        "INSERT INTO "+ТаблицаSQL+"
        |([C_DateTime], [C_Char], [C_Numeric])
        |VALUES ('"+ТекДата+"', N'"+ТекСтрока+"', '"+ТекЧисло+"')";
    Попытка
        Соединение.Execute(ТекстТекущейИнструкции,,128);
        Сообщить("Запись добавлена!");
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;

Смотрим результат и видим, что строка появилась в таблице:

podkly-k-sql-iz-1s_006

4. Обновление записей в таблице

Теперь попробуем обновить все записи в таблице со значением C_Numeric=123456. Для этого выполняем код:

    /////////////////////////////////////////
    //Обновляем записи в таблице с C_Numeric = 123456
    ТекЧисло = 123456;
    ТекДатаНовая = Дата(1,1,1);
    ТекСтрокаНовая = "Обновленная запись строки";

    //Приобразуем данные
    Если НЕ ЗначениеЗаполнено(ТекДатаНовая) Тогда
        //Для пустой даты необходимо отправлять 01.01.1753
        ТекДатаНовая = Дата(1753,1,1);
    КонецЕсли;
    ТекЧисло = Формат(ТекЧисло,"ЧГ="); //Удаляем пробелы

    ТекстТекущейИнструкции =
        "UPDATE "+ТаблицаSQL+"
        |SET
        |   [C_Char] = N'"+ТекСтрокаНовая+"',
        |   [C_DateTime] = '"+ТекДатаНовая+"'
        |WHERE [C_Numeric]='"+ТекЧисло+"'";
    Попытка
        Соединение.Execute(ТекстТекущейИнструкции,,128);
        Сообщить("Запись обновлена!");
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;

Проверяем, что запись обновилась:

podkly-k-sql-iz-1s_007

5. Просмотр выборки из таблицы

Писать и обновлять записи в таблице мы научились. Теперь посмотрим как просматривать выборку из запроса с SQL-сервера:

    /////////////////////////////////////////
    //Читаем записи
    ТекстИнструкции =
        "SELECT
        |   [C_DateTime], [C_Char], [C_Numeric]
        |FROM "+ТаблицаSQL;
    Попытка
        Команда.CommandText = ТекстИнструкции;
        Выборка = Команда.Execute();
        Если Выборка.BOF = Ложь Тогда
            Выборка.MoveFirst();
            Пока Выборка.EOF = Ложь Цикл
                Сообщить("[C_DateTime]="+Дата(Выборка.Fields("C_DateTime").Value)
                    +", [C_Char]="+СокрЛП(Выборка.Fields("C_Char").Value)
                    +", [C_Numeric]="+Число(Выборка.Fields("C_Numeric").Value));
                Выборка.MoveNext();
            КонецЦикла;
        КонецЕсли;
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;

Результат в предприятии:

podkly-k-sql-iz-1s_008

6. Удаление записей из таблицы

Для удаления всех записей в таблице со значением C_Numeric=123456 выполняем код:

    /////////////////////////////////////////
    //Удаляем записи в таблице с C_Numeric = 123456
    ТекЧисло = 123456;
    ТекЧисло = Формат(ТекЧисло,"ЧГ="); //Удаляем пробелы

    ТекстТекущейИнструкции =
        "DELETE FROM "+ТаблицаSQL+"
        |WHERE [C_Numeric]='"+ТекЧисло+"'";
    Попытка
        Соединение.Execute(ТекстТекущейИнструкции,,128);
        Сообщить("Запись удалена!");
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;

Проверяем, что записей в таблице не осталось:

podkly-k-sql-iz-1s_009

7. Закрытие соединения

Ну и после выполнения всех необходимых действий необходимо закрыть соединение с SQL-сервером. Для этого достаточно вызвать метод Close() созданного COM-объекта:

    /////////////////////////////////////////
    //Закрытия соединения
    Попытка
        Соединение.Close();
        Сообщить("Соединение закрыто!");
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;

8. Общий текст процедуры

Общий текст всей процедуры получился следующий:

&НаКлиенте
Процедура ВыполнитьОбработку(Команда)

    //Инициализация переменных
    ИмяСервераSQL = "WIN2012\TEST_SQL";
    ПользовательSQL = "UserDB";
    ПарольSQL = "Pass123456";
    БазаДанныхSQL = "TestDB";
    ТаблицаSQL = "Table_1";


    /////////////////////////////////////////
    //Подключение к SQL-серверу
    Попытка
        Соединение  = Новый COMОбъект("ADODB.Connection");
        Команда     = Новый COMОбъект("ADODB.Command");
        Выборка     = Новый COMОбъект("ADODB.RecordSet");
        Соединение.ConnectionString =
            "driver={SQL Server};" +
            "server="+ИмяСервераSQL+";"+
            "uid="+ПользовательSQL+";"+
            "pwd="+ПарольSQL+";"+
            "database="+БазаДанныхSQL+";";
        Соединение.ConnectionTimeout = 30;
        Соединение.CommandTimeout = 600;
        //Открытие соединение
        Соединение.Open();
        Команда.ActiveConnection   = Соединение;
        Сообщить("Успешное подключение!");
    Исключение
        Сообщить(ОписаниеОшибки());
        Возврат;
    КонецПопытки;


    /////////////////////////////////////////
    //Добавляем запись в таблицу
    ТекДата = ТекущаяДата();
    ТекСтрока = "Запись строки";
    ТекЧисло = 123456;

    //Приобразуем данные
    Если НЕ ЗначениеЗаполнено(ТекДата) Тогда
        //Для пустой даты необходимо отправлять 01.01.1753
        ТекДата = Дата(1753,1,1);
    КонецЕсли;
    ТекЧисло = Формат(ТекЧисло,"ЧГ="); //Удаляем пробелы

    ТекстТекущейИнструкции =
        "INSERT INTO "+ТаблицаSQL+"
        |([C_DateTime], [C_Char], [C_Numeric])
        |VALUES ('"+ТекДата+"', N'"+ТекСтрока+"', '"+ТекЧисло+"')";
    Попытка
        Соединение.Execute(ТекстТекущейИнструкции,,128);
        Сообщить("Запись добавлена!");
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;


    /////////////////////////////////////////
    //Обновляем записи в таблице с C_Numeric = 123456
    ТекЧисло = 123456;
    ТекДатаНовая = Дата(1,1,1);
    ТекСтрокаНовая = "Обновленная запись строки";

    //Приобразуем данные
    Если НЕ ЗначениеЗаполнено(ТекДатаНовая) Тогда
        //Для пустой даты необходимо отправлять 01.01.1753
        ТекДатаНовая = Дата(1753,1,1);
    КонецЕсли;
    ТекЧисло = Формат(ТекЧисло,"ЧГ="); //Удаляем пробелы

    ТекстТекущейИнструкции =
        "UPDATE "+ТаблицаSQL+"
        |SET
        |   [C_Char] = N'"+ТекСтрокаНовая+"',
        |   [C_DateTime] = '"+ТекДатаНовая+"'
        |WHERE [C_Numeric]='"+ТекЧисло+"'";
    Попытка
        Соединение.Execute(ТекстТекущейИнструкции,,128);
        Сообщить("Запись обновлена!");
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;

    /////////////////////////////////////////
    //Читаем записи
    ТекстИнструкции =
        "SELECT
        |   [C_DateTime], [C_Char], [C_Numeric]
        |FROM "+ТаблицаSQL;
    Попытка
        Команда.CommandText = ТекстИнструкции;
        Выборка = Команда.Execute();
        Если Выборка.BOF = Ложь Тогда
            Выборка.MoveFirst();
            Пока Выборка.EOF = Ложь Цикл
                Сообщить("[C_DateTime]="+Дата(Выборка.Fields("C_DateTime").Value)
                    +", [C_Char]="+СокрЛП(Выборка.Fields("C_Char").Value)
                    +", [C_Numeric]="+Число(Выборка.Fields("C_Numeric").Value));
                Выборка.MoveNext();
            КонецЦикла;
        КонецЕсли;
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;

    /////////////////////////////////////////
    //Удаляем записи в таблице с C_Numeric = 123456
    ТекЧисло = 123456;
    ТекЧисло = Формат(ТекЧисло,"ЧГ="); //Удаляем пробелы

    ТекстТекущейИнструкции =
        "DELETE FROM "+ТаблицаSQL+"
        |WHERE [C_Numeric]='"+ТекЧисло+"'";
    Попытка
        Соединение.Execute(ТекстТекущейИнструкции,,128);
        Сообщить("Запись удалена!");
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;


    /////////////////////////////////////////
    //Закрытия соединения
    Попытка
        Соединение.Close();
        Сообщить("Соединение закрыто!");
    Исключение
        Сообщить(ОписаниеОшибки());
    КонецПопытки;

КонецПроцедуры

Результат работы в 1С:Предприятии:

podkly-k-sql-iz-1s_010

Помогла ли вам данная статья?
Да, спасибо, все получилось.
Немного помогла.
Совсем не помогла.
Не то, что я искал(а).
Смотреть результаты

Смотрите также:

  • Правила доработки типовых конфигураций 1С

    В данном вебинаре я расскажу о применяемых в нашей компании правилах и приемах доработки типовых конфигураций 1С для облегчения их дальнейшей поддержки и обновления.     В видео использованы материалы…

  • Установка 1С:Предприятие 7.7 на Microsoft SQL Server 2008 R2

    Официально, платформа 1С:Предприятие 7.7 работает только с MS SQL Server 2000. Но с помощью небольших манипуляций можно организовать стабильную работу и с последней, на момент написания статьи, версий Microsoft SQL…

  • Если бы 1С-ники делали трубы

    Небольшая зарисовка на тему, какие были бы сливные трубы, если бы их делали 1С-ники.

Запись опубликована в рубрике Разработка в 1С с метками , , . Добавьте в закладки постоянную ссылку.


41 Responses to Подключение к SQL-серверу из 1С:Предприятие 8 (пример кода)

  1. myr4ik07 говорит:
    23.06.2016 в 16:17

    Дуже корисно. Дякую.

    Ответить
  2. Олег говорит:
    29.06.2017 в 02:59

    Спасибо, очень помогли!

    Ответить
  3. Алексей говорит:
    18.07.2017 в 12:45

    Отличная интересная статья о том как можно подключить свою страницу в интернете к 1с предприятию — очень удобно управлять торговлей.

    Ответить
  4. Аноним говорит:
    19.12.2018 в 22:37

    Utf-8 не понимает как исправить?
    записивает как ??????

    Ответить
  5. Аноним говорит:
    09.04.2019 в 13:52

    как можно таблицу в SQL загрузить сразу в массив или в тз? Вижу только выборку

    Ответить
  6. Александр говорит:
    30.04.2019 в 11:29

    Спасибо тебе добрый человек

    Ответить
  7. Анон говорит:
    15.06.2019 в 18:46

    Очень полезная инфа. Огромное спасибо

    Ответить
  8. Аноним говорит:
    11.07.2019 в 19:04

    отличная статья

    Ответить
  9. David говорит:
    10.12.2019 в 19:32

    Добрый день. А как подключиться к SQL, если он на другом компе в локальной сети.
    Спасибо.

    Ответить
    • Виталий Онянов говорит:
      18.01.2020 в 12:22

      Здравствуйте.

      Все то же самое, только в свойствах подключения (ИмяСервераSQL) указываете адрес компьютера с SQL Server.

      Ответить
  10. Аноним говорит:
    06.02.2020 в 14:57

    Спасибо

    Ответить
  11. wmon говорит:
    19.03.2020 в 01:12

    Приветствую!
    Подскажите пожалуйста насчет строки «driver={SQL Server};»
    Я так понимаю нужно указать правильный драйвер для подключения к серверу….
    Как узнать что за драйвер там стоит? Или этот драйвер надо установить и на компе где 1С установлен? SQL Server у меня на другом компе…

    Ответить
    • Виталий Онянов говорит:
      23.05.2020 в 11:24

      Да, драйвер должен быть на компьютере, откуда вы подключаетесь. Если код выполняется на сервере — то на сервере с кластером серверов 1С, если на клиенте, то, соответственно, на клиенте.

      В системе Windows для SQL Server уже есть все необходимые драйвера. Специально ничего ставить не надо.

      Посмотреть версию драйвера можно в программе «Источники данных ODBC», поищите поиском в меню «Пуск».

      Ответить
  12. wmon говорит:
    20.03.2020 в 01:49

    С подключением и драйвером разобрался… Все ок.
    Подскажите пожалуйста, как добавить в таблицу SQL сразу все записи из выборки ?
    Т.е сейчас у меня так:
    РезЗапроса = Запрос.Выполнить().Выбрать();
    Пока РезЗапроса.Следующий() Цикл

    ТекстТекущейИнструкции =

    «INSERT INTO «+ТаблицаSQL+»
    |([StockAdministration], [ItemCode])
    |VALUES (N'»+РезЗапроса.Код+»‘, ‘»+РезЗапроса.Сум+»‘, )»;

    Попытка
    Соединение.Execute(ТекстТекущейИнструкции,,128);
    //Сообщить(«Запись добавлена!»);
    Исключение
    Сообщить(ОписаниеОшибки());
    КонецПопытки;
    КонецЦикла;

    Возможно ли оптимизировать?

    Ответить
    • Виталий Онянов говорит:
      23.05.2020 в 11:27

      Да, конечно, можно сделать так:

      РезЗапроса = Запрос.Выполнить().Выбрать();
ТекстТекущейИнструкции = "";
Пока РезЗапроса.Следующий() Цикл

	ТекстТекущейИнструкции = ТекстТекущейИнструкции + Символы.ПС + 

	"INSERT INTO "+ТаблицаSQL+"
	|([StockAdministration], [ItemCode])
	|VALUES (N'»+РезЗапроса.Код+»‘, ‘»+РезЗапроса.Сум+»‘, )";
	
КонецЦикла;

Попытка
	Соединение.Execute(ТекстТекущейИнструкции,,128);
Исключение
	Сообщить(ОписаниеОшибки());
КонецПопытки;
      Ответить
  13. Armastus говорит:
    07.05.2020 в 19:51

    Добрый день, Виталий! Большое спасибо за статью, выручала раньше, но тут случилась проруха — а именно база MySQL на Unix серевере((( Какого провайдера нужно указывать в таком случае и как посмотреть на Unix серевере, какие драйвера установлены и используются?

    Ответить
    • Виталий Онянов говорит:
      23.05.2020 в 11:19

      Здравствуйте. Для MySQL используется вот этот драйвер (нужной версии).

      Пример кода:

      	Попытка
		Соединение  = Новый COMОбъект("ADODB.Connection");
		Команда     = Новый COMОбъект("ADODB.Command");
		Соединение.ConnectionString ="driver={MySQL ODBC 5.3 ANSI Driver}; PORT=" + Формат(НастройкиИнтеграции.Порт,"ЧГ=") + ";" +
			"SERVER="+НастройкиИнтеграции.Адрес+";"+
			"uid="+НастройкиИнтеграции.ИмяПользователя+";"+
			"pwd="+НастройкиИнтеграции.ПарольПользователя+";"+
			"database="+НастройкиИнтеграции.ИмяБазыДанных+";";

		//Открытие соединение
		Соединение.Open();
		Команда.ActiveConnection = Соединение;
	Исключение
		ДобавитьТекстОшибки(ИнформацияОбОшибке());
		Возврат;
	КонецПопытки;
      Ответить
  14. ищущий правду. говорит:
    21.05.2020 в 20:51

    Аккуратно написанный хелп. Инструкция /памятка.Большое спасибо.

    Ответить
  15. Аноним говорит:
    21.08.2020 в 16:19

    Спасибо !

    Ответить
  16. Никита говорит:
    20.01.2021 в 10:57

    Здравствуйте, а как вот добавить записи из таблицы sql в 1с, в справочник допустим?

    Ответить
    • Никита говорит:
      20.01.2021 в 10:59

      Даже не так, загрузить уже имеющиеся данные из таблицы sql в 1с

      Ответить
    • Виталий Онянов говорит:
      11.02.2021 в 13:13

      Вместо строчки

      Сообщить("[C_DateTime]="+Дата(Выборка.Fields("C_DateTime").Value)
+", [C_Char]="+СокрЛП(Выборка.Fields("C_Char").Value)
+", [C_Numeric]="+Число(Выборка.Fields("C_Numeric").Value));

      Необходимо описать логику добавления данных в 1С. Здесь уже все зависит от ваших требований и квалификации.

      Ответить
  17. Роман говорит:
    20.01.2021 в 22:33

    Приветствую. А можно ли подключиться в локальной сети без Com вообще?
    Com только для винды. А там все на Линуксах. И без web сервисов всяких, по локалке, знаешь имя сервера имя базы, логин и пароль

    Ответить
  18. Андрей говорит:
    03.11.2021 в 20:01

    Скрипт:
    USE [master]
    GO
    ALTER DATABASE [UH_Test_DB] SET OFFLINE
    GO

    Возвращает ошибку:
    {Справочник.ИнформационныеБазы.Форма.ФормаСписка.Форма(80)}: Ошибка при вызове метода контекста (Execute): Произошла исключительная ситуация (Microsoft OLE DB Provider for ODBC Drivers): [Microsoft][ODBC SQL Server Driver][SQL Server]Incorrect syntax near ‘GO’.

    При этом коннект успешно
    Может ли ODBC выполнять подобные скрипты ?

    Ответить
    • Виталий Онянов говорит:
      05.11.2021 в 14:25

      Разницы не должно быть.
      Проверьте, выполняется ли этот скрипт в SQL Management Studio?

      Ответить
      • Аноним говорит:
        08.11.2021 в 12:45

        Да в SQL MS скрипт выполняется.
        Кстати и скрит на выборку (в контексте 1С, через ODBC драйвер) тоже выполняется успешно.

        Ответить
        • Аноним говорит:
          08.11.2021 в 18:36

          USE [master]
          ALTER DATABASE [UH_Test_DB] SET OFFLINE

          Так сработало. Спасибо)

          Ответить
          • Виталий Онянов говорит:
            10.12.2021 в 19:30

            Спасибо, что поделились решением.

  19. Аноним говорит:
    12.11.2021 в 12:57

    Может кому пригодится.
    Кроме параметра-Соединение.CommandTimeout
    Есть еще параметр-Команда.CommandTimeout

    Ответить
  20. EkimovDA говорит:
    26.12.2021 в 22:40

    Большое спасибо за информацию

    Ответить
  21. Аноним говорит:
    05.05.2022 в 18:12

    Использовать Формат() в данном случае – порочная практика. Гораздо лучше и правильнее использовать XMLСтрока().

    Ответить
    • Виталий Онянов говорит:
      16.05.2022 в 13:33

      Наверное, вы правы, спасибо. Только не могу придумать, чем все же плохо использование Формат() ?

      Ответить
  22. Крис говорит:
    12.07.2022 в 14:07

    Здравствуйте! А как удалить таблицу при помощи TRUNCATE? Никак не получается!

    Ответить
  23. Sergey Seredkin (SPS) говорит:
    28.10.2022 в 22:56

    Надо помнить что SQL поддерживает примитивные данные строка число дата и тд. Поэтому при связки с 1С придётся всегда применять что то типа арбуз=Справочник.Номенклатур.НайтиПоНаименованию(«арбуз») . А затем только создавать документ продаж с этой номенклатурой., так как в ске ключевые данные справочников ., документов это ссылки.

    Ответить
  24. Ирина говорит:
    15.03.2023 в 19:37

    Здравствуйте. Спасибо за полезную статью. Но никак не могу разобраться с кодировкой. При чтении из базы SQL символы на кириллице отображаются как ?????, Что нужно сделать?

    Ответить
  25. Аноним говорит:
    26.07.2023 в 02:08

    Добавте пример — закинут в таблицу картинку или файл, чтобы передаваемые значения были не в строке а через параметры.

    Ответить
  26. Виктор говорит:
    02.06.2024 в 03:43

    Хочу отметить одну не очень важную вещь. Когда делаете манипуляции с базой и через параметры пример ниже то не забываем очищать параметры иначе не чего не получится.
    ПРИМЕР как можно еще делать Только часть условия:
    //Инициализация глабальных переменных
    ИмяСервераSQL = «Имя сервера»;
    ПользовательSQL = «пользователь базы с правами»;
    ПарольSQL = «Пароль»;
    БазаДанныхSQL = «Имя базы данных»;
    ТаблицаSQL = «Склад»;
    Код = СокрЛП(Код); //Удаляем пробелы

    /////////////////////////////////////////
    // Подключение к SQL-серверу
    Попытка

    Соединение = Новый COMОбъект(«ADODB.Connection»);
    Команда = Новый COMОбъект(«ADODB.Command»);
    Выборка = Новый COMОбъект(«ADODB.RecordSet»);

    //Соединение = Новый COMОбъект(«ADODB.Connection»);
    Соединение.ConnectionString =
    «driver={SQL Server};» +
    «server=» + ИмяСервераSQL + «;» +
    «uid=» + ПользовательSQL + «;» +
    «pwd=» + ПарольSQL + «;» +
    «database=» + БазаДанныхSQL + «;»;

    Соединение.ConnectionTimeout = 30;
    Соединение.CommandTimeout = 600;
    Соединение.Open();

    Команда.ActiveConnection = Соединение;
    Исключение
    Сообщить(«Ошибка подключения к базе данных » + БазаДанныхSQL + «: » + ОписаниеОшибки());
    Возврат;
    КонецПопытки;
    Попытка
    // Проверяем существование строки
    ТекстИнструкции = «SELECT COUNT(*) FROM » + ТаблицаSQL + » WHERE [Код] = ?»;
    Команда.CommandText = ТекстИнструкции;
    Команда.CommandType = 1; // adCmdText

    // Удаление параметров, если они уже существуют
    Пока Команда.Parameters.Count > 0 Цикл
    Команда.Parameters.Delete(0);
    КонецЦикла;

    // Передача параметра запроса
    Команда.Parameters.Append(Команда.CreateParameter(«Код», 202, 1, 9, Код)); // adVarWChar

    // Выполняем запрос для проверки существования строки
    Выборка = Команда.Execute();
    Если Выборка.Fields(0).Value > 0 Тогда
    // тут часть кода когда нашли уже существующию строку и будем обновлять.
    Иначе
    // Строка не существует, выполняем добавление
    ТекстИнструкции = «INSERT INTO » + ТаблицаSQL + » ([Код], [НаименованиеСклада], [Адрес]) VALUES (?,?,?)»;
    Команда.CommandText = ТекстИнструкции;

    // Передача параметров запроса
    Команда.CommandType = 1; // adCmdText

    // Удаление параметров, если они уже существуют иначе подтянутся старые
    //параметры
    Пока Команда.Parameters.Count > 0 Цикл
    Команда.Parameters.Delete(0);
    КонецЦикла;

    // Передача параметра запроса
    Команда.Parameters.Append(Команда.CreateParameter(«Код», 202, 1, 9, Код)); // adVarWChar
    Команда.Parameters.Append(Команда.CreateParameter(«НаименованиеСклада», 202, 1, 25, Наименование)); // adVarWChar
    Команда.Parameters.Append(Команда.CreateParameter(«Адрес», 202, 1, 25, Адрес)); // adVarWChar

    // Выполнение команды
    Команда.Execute();
    // Закрытие соединения
    Соединение.Close();
    КонецЕсли;
    Исключение
    Сообщить(«Ошибка: » + ОписаниеОшибки());
    Если Соединение Неопределено Тогда
    Соединение.Close();
    КонецЕсли;
    КонецПопытки;

    КонецПроцедуры

    Ответить
  27. Иван говорит:
    07.08.2024 в 10:29

    Народ, подскажите! Дано 1с 7.7 на SQL, через менеджер sql могу войти во все базы. но 1с пишет ошибку, и предлагает настроить подключение заново. Админа этого сервера давно нету — как восстановить настройки?! Спасибо!!!

    Ответить

Добавить комментарий

Ваш адрес email не будет опубликован. Обязательные поля помечены *